Pytanie Jak mogę zaimplementować mój własny edytor właściwości dla wszystkich wystąpień określonego typu?


Po zapoznaniu się z kilkoma samouczkami dotyczącymi tworzenia okna dialogowego edytora właściwości niestandardowych, ale jest tak wiele rzeczy, których nie mogłem zapewnić, by działał prawidłowo. Próbuję wykonać niestandardowy formularz z selektorem dat (kalendarz), selektorem czasu oraz przyciskami OK i Anuluj. Formularz nie stanowi problemu, ale jak mam go wdrożyć, aby móc opublikować właściwość dowolnego komponentu określonego typu za pomocą przycisku uruchamiającego edytor właściwości?

Chciałbym całkowicie uchylić TDateTime wpisz i umieść mój własny edytor na swoim miejscu, więc gdziekolwiek TDateTime jest opublikowany i widoczny w Inspektorze obiektów, mogę użyć tego edytora do modyfikacji daty i czasu razem w tym samym oknie.

Problem polega na tym, że dokumentacja dotycząca tworzenia edytora właściwości niestandardowych jest słaba i chociaż niektóre zasoby są bardzo szczegółowe, zbyt wiele szczegółów dotyczących możliwości i braków w zrozumieniu najczęstszych scenariuszy.


10
2017-12-19 02:47


pochodzenie




Odpowiedzi:


Nie chciałem tu zadawać tego pytania i oczekiwać, że ktoś mi na nie odpowie, więc sam przeprowadziłem badania, aby rozwiązać moje problemy i chciałbym podzielić się wyjątkowym doświadczeniem związanym z tym mini projektem, ponieważ jestem pewien, że inni sfrustrowany tym samym.

Istnieje wiele różnych możliwości dzięki niestandardowym edytorom właściwości, oknom dialogowym i edytorom komponentów. W szczególności wymagałoby to TDateTimeProperty potomek. Umożliwi to edycję wartości właściwości bezpośrednio w Inspektorze obiektów jako tekst zwykły (String) przy zachowaniu formatowania DateTime.

Zakładam, że masz już ogólną wiedzę na temat tworzenia niestandardowych komponentów i pakietu, w którym możesz opublikować edytor właściwości, ponieważ jest to lekcja sama w sobie, której nie omówię. Wymaga to umieszczenia tylko jednej linii kodu w Register procedura, ale do tego dojdziemy później.

Najpierw musisz utworzyć nowy formularz w swoim Design-Time pakiet, w którym zarejestrowane są twoje składniki. Nazwij jednostkę DateTimeProperty.pasi nazwij formularz DateTimeDialog (w ten sposób tworząc klasę formularza TDateTimeDialog). Umieść potrzebne elementy sterujące, w tym przypadku a TMonthCalendar, TDateTimePicker (z Kind Ustawić dtkTime) i 2 TBitBtn kontrole, jedno oznakowane OK z ModalResult z mrOK a drugi oznaczony Cancel z ModalResult z mrCancel.

Twoja jednostka powinna wyglądać mniej więcej tak:

unit DateTimeProperty;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
  System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs,
  Vcl.ComCtrls, Vcl.StdCtrls, Vcl.Buttons;

type
  TDateTimeDialog = class(TForm)
    dtDate: TMonthCalendar;
    dtTime: TDateTimePicker;
    BitBtn1: TBitBtn;
    BitBtn2: TBitBtn;
  private

  public

  end;         

var
  DateTimeDialog: TDateTimeDialog;

implementation

{$R *.dfm}

end.

I oto jest DFM kod za tym formularzem:

object DateTimeDialog: TDateTimeDialog
  Left = 591
  Top = 158
  BorderIcons = [biSystemMenu]
  BorderStyle = bsToolWindow
  Caption = 'Pick Date/Time'
  ClientHeight = 231
  ClientWidth = 241
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'Tahoma'
  Font.Style = []
  OldCreateOrder = False
  Position = poScreenCenter
  DesignSize = (
    241
    231)
  PixelsPerInch = 96
  TextHeight = 13
  object dtDate: TMonthCalendar
    Left = 8
    Top = 31
    Width = 225
    Height = 166
    Anchors = [akLeft, akRight, akBottom]
    Date = 41261.901190613430000000
    TabOrder = 1
  end
  object dtTime: TDateTimePicker
    Left = 8
    Top = 8
    Width = 113
    Height = 21
    Date = 41261.000000000000000000
    Time = 41261.000000000000000000
    Kind = dtkTime
    TabOrder = 2
  end
  object BitBtn1: TBitBtn
    Left = 158
    Top = 200
    Width = 75
    Height = 25
    Caption = 'OK'
    Default = True
    ModalResult = 1
    TabOrder = 0
  end
  object BitBtn2: TBitBtn
    Left = 77
    Top = 200
    Width = 75
    Height = 25
    Caption = 'Cancel'
    ModalResult = 2
    TabOrder = 3
  end
end

Teraz dodaj DesignEditors i DesignIntf dla Twojej uses klauzula. Upewnij się że masz DesignIDE zadeklarowane w Requires tego Design-Time pakiet. Jest to wymagane do publikowania dowolnych edytorów właściwości.

W formularzu utwórz nową właściwość publiczną o nazwie DateTime typu TDateTime z narzędziem pobierającym i ustawiającym własności. Ta właściwość pozwoli Ci w łatwy sposób odczytać / zapisać pełny TDateTime wartość, którą faktycznie reprezentuje wybór. Powinieneś mieć to w swojej formie:

private
  function GetDateTime: TDateTime;
  procedure SetDateTime(const Value: TDateTime);
public
  property DateTime: TDateTime read GetDateTime write SetDateTime;

....

function TDateTimeDialog.GetDateTime: TDateTime;
begin
  Result:= Int(dtDate.Date) + Frac(dtTime.Time);
end;

procedure TDateTimeDialog.SetDateTime(const Value: TDateTime);
begin
  dtDate.Date:= Value;
  dtTime.DateTime:= Value;
end;

Następnie musimy dodać rzeczywistą klasę edytora właściwości. Utwórz tę klasę tuż pod {$R *.dfm}który jest tuż poniżej implementation:

type
  TDateTimeEditor = class(TDateTimeProperty)
  public
    procedure Edit; override;
    function GetAttributes: TPropertyAttributes; override;
    function GetValue: String; override;
    procedure SetValue(const Value: String); override;
  end;

procedure TDateTimeEditor.Edit;
var
  F: TDateTimeDialog;
begin
  //Initialize the property editor window
  F:= TDateTimeDialog.Create(Application);
  try
    F.DateTime:= GetFloatValue;
    if F.ShowModal = mrOK then begin
      SetFloatValue(F.DateTime);
    end;
  finally
    F.Free;
  end;
end;

function TDateTimeEditor.GetAttributes: TPropertyAttributes;
begin
  //Makes the small button show to the right of the property
  Result := inherited GetAttributes + [paDialog];
end;

function TDateTimeEditor.GetValue: String;
begin
  //Returns the string which should show in Object Inspector
  Result:= FormatDateTime('m/d/yy h:nn:ss ampm', GetFloatValue);
end;

procedure TDateTimeEditor.SetValue(const Value: String);
begin
  //Assigns the string typed in Object Inspector to the property
  inherited;
end;

Wreszcie, musimy dodać Register procedura wykonania faktycznej rejestracji tego nowego edytora właściwości:

procedure Register;
begin
  RegisterPropertyEditor(TypeInfo(TDateTime), nil, '', TDateTimeEditor);
end;

W tej rozmowie jest ważny element do zrozumienia RegisterPropertyEditor. Ponieważ 2 i 3 parametry są nil i pusty ciąg znaków, oznacza to, że edytor będzie stosowany do wszystkich instancji TDateTime. Zapoznaj się z tą procedurą, aby uzyskać więcej informacji na temat dostosowania jej do określonych składników i wystąpień właściwości.

A oto ostateczny wynik po zainstalowaniu ...

Sample of final property editor

Niektóre dobre zasoby dla edytorów niestandardowych właściwości, które przyczyniły się, są następujące:

  1. jak zrobić niestandardową właściwość komponentu?
  2. http://delphi.about.com/library/bluc/text/uc092501d.htm
  3. http://www.sandownet.com/propedit.html

14
2017-12-19 02:47



więcej dobrych zasobów może być bibliotekami FLOSS, takimi jak CnWizards lub JediVCL, które implementują i rejestrują niektóre edytory właściwości globalnych, po prostu czytają i uczą się - Arioch 'The
I nie zapomnij o Rayu Konopce Opracowywanie niestandardowych komponentów Delphi 3 D3 i nie jest już drukowany, ale nadal ma zastosowanie. Ray ma wersję pdf na sprzedaż na swojej stronie: raize.com/DevTools/Ordering/Pricing.asp - Marjan Venema
+1 Ładnie zrobione. Zmieniłby jednak kolejność kontrolowania czasu i daty ... ;-) - NGLN
+1 Nie rozumiem, dlaczego przesłoniłeś GetValue i SetValue. W szczególności GetValue wymusza preferowany format daty na świecie. Ale SetValue nie robi. Po prostu usunę te dwie metody. - David Heffernan
@DavidHeffernan Tak, zgadzam się, chciałem podkreślić, że można go przesłonić do sprawdzania poprawności itp., Chociaż nie wyjaśniłem tej części. - Jerry Dodge